; general device setup
; this is for the ATtiny 45/85
; 
.NOLIST                ; Disable listfile generation 
.include "tn45def.inc"
.LIST
; ******************************************************************
; todays project:
; build a drop-in replacement for the HS1527 OTP encoder
; base is the RCT-08 encoder from Pollin ( replacement transmitter for the home - 3 dimmers included bundle)
; constants @ 8 Mhz clk 
; ******************************************************************
; might contain remains of a similar ATTiny 2313 project
; timings

.equ	atomtime	= 250	; usecs
; 8 bit / 8 timer ( 8 usecs)
.equ	shorttime 	= 256-30
.equ	longtime 	= 256-95
.equ	pretime		= 256-9300
;

.equ	ROMSTART	= 0x0100
.equ	RAMSTART	= SRAM_START
.equ	cr		= 0x0d
.equ	lf		= 0x0a
.equ	spc		= 0x20
.equ	US30		= 0x02
.equ	MS1		= 0x14
.equ	MS5		= 0x28
.equ	MS7		= 0x2b
.equ	MS10		= 0x33
.equ	MS30		= 0x4b
.equ	MS100		= 0x71		; roughly 100mS with wozwait @ 8Mhz
.equ	MS500		= 0xc8		; roughly 500mS with wozwait @ 8Mhz
.equ	second		= 0xe6		; roughly a second with wozwait @ 8Mhz
;
; pinning on the ATTiny 45 mimics former 1527 
; if soldered one pin shifted (tiny GND = HS GND )
; port B
.equ	SCK	= 4	; TX 
.equ	TXDATA	= SCK
; inputs from keys 
; 
; pin names from HS1527 
.equ	DATA3	= 3	;  K4
.equ	DATA0	= 0	;  K0
; row inputs
.equ	DATA1	= 1	;  K1

.equ	DATA2	= 2	;  K2
;
; 
; irq registers
.def	irqstor		= r12		; IRQ routine SREG safe place
; general purpose non-immediate
.def	lowtemp 	= r13
; immediate registers
.def	temp	= r16	;misc usage, general purpose
.def	loop	= r17
.def	del	= r18	; delay counter
.def	tilo	= r19	; timerloader
.def	tihi	= r20	; timerloader
.def	buffer	= r21	; sendbyte
.def	counter = r22	; bitbanger
.def	command	= r23	; button
; flags for operation 
;7	6	5	4	3	2	1	0
;start
.def    flags = r25	; flags	
; **************   MAIN PROGRAM STARTS HERE *************************
.CSEG 
	.ORG	0x0
; for ATTiny 25/45/85
 	rjmp 	RESET 		; Reset Handler
 	rjmp 	EXT_INT0 	; IRQ0 Handler
 	rjmp 	PC_INT0 	; PCINT0 Handler
	rjmp	TIM1_COMPA	; Timer 1 compare match A
	rjmp	TIM1_OVF	; timer 1 overflow	
 	rjmp 	TIM0_OVF 	; Timer0 Overflow Handler
 	rjmp 	EE_RDY 		; EEPROM Ready Handler
 	rjmp 	ANA_COMP 	; Analog Comparator Handler
 	rjmp 	ADC_INT 	; ADC Conversion Handler
	rjmp	TIM1_COMPB	; timer 1 compare match B
 	rjmp 	TIM0_COMPA 	; Timer0 CompareA Handler
 	rjmp 	TIM0_COMPB 	; Timer0 CompareB Handler
 	rjmp 	WATCHDOG 	; Watchdog Interrupt Handler
	rjmp	USI_START	; usi start condition
	rjmp	USI_OVF		; usi overflow

;
; IRQ routines are not used today
; stubs
EXT_INT0:		 ; External Interrupt0 Handler
PC_INT0:          	; Pin Change Interrupt
TIM1_COMPA:     	; Timer1 CompareA Handler
TIM1_OVF:       	; Timer1 Overflow Handler
TIM0_OVF:       	; Timer0 Overflow Handler
EE_RDY:       		; EEPROM Ready Handler
ANA_COMP:       	; Analog Comparator Handler 
ADC_INT:			; ADC ready
TIM1_COMPB:   		; Timer1 Compare B Handler
TIM0_COMPA:   		; Timer0 Compare A Handler
TIM0_COMPB:   		; Timer0 Compare B Handler
USI_START:      	; USI Start Handler
USI_OVF:   		; USI Overflow Handler
WATCHDOG:   		; Watchdog Overflow Handler
	reti
RESET:	nop
	nop
	ldi	temp,low(RAMEND)
	out	SPL,temp
; the Tiny25 doesn't come with SPH
#ifndef _TN25DEF_INC_
	ldi	temp,high(RAMEND) 
	out	SPH, temphi
#endif
	cli
; switch off the WDT
	wdr
	in	temp,MCUSR
	andi	temp,(0xff & (0<<WDRF))
	out	MCUSR,temp
	in	temp,WDTCSR
	ori	temp,(1<<WDCE) | (1<<WDE)
	out	WDTCSR,temp
	ldi	temp,(0<<WDE)
	out	WDTCSR,temp
; wdt is finally off
	rcall	init_ports			
	sei
;first sleep	

main:	rcall	time2		;timers off
	ldi	del,MS10
	rcall	wozwait
main3:	in	command,PinB	; read the keys
;
;subprograms
; i say it five times
send:	rcall	sendstring
	rcall	sendstring
	rcall	sendstring
	rcall	sendstring
	rcall	sendstring
	rjmp	main3
; send the command string with 3 bytes
; 
sendstring:
	rcall	sendpre
	andi	command,0x0f	;mask to 16 channels
	push	command	
	ldi	ZH,high(tx_tab << 1)  ; set Z-Register to start of commandtab
	ldi	ZL,low(tx_tab << 1)
	lsl	command		;	* 2
	lsl	command		; 	* 4
	clc
	clr	temp
	add	ZL,command
	adc	ZH,temp		; Z now points to start of code
	ldi	loop,0x03	; 3 bytes to send
send1:	lpm	buffer,Z+
	rcall	sendbyte
	dec	loop
	brne	send1
	pop	command
	ret

sendbyte:
	ldi	counter,0x08
sendby3:
	lsl	buffer
	brcc	sendby1
	rcall	sendone
	rjmp	sendby2
sendby1:
	rcall	sendzero
sendby2:dec	counter
	brne	sendby3
	ret	
	
; send a zero
sendzero:
	sbi	PortB,TXDATA	; short high
	rcall	sendshort
	cbi	PortB,TXDATA	;long low
	rjmp	sendlong	;exit via timer
; send a one
sendone:
	sbi	PortB,TXDATA	; long high
	rcall	sendlong	;
	cbi	PortB,TXDATA	;long low
	rjmp	sendshort	;exit via timer
; send the preamble
sendpre:
	sbi	PortB,TXDATA	; short high
	rcall	sendshort
sendpre2:
	cbi	PortB,TXDATA	;long low
	ldi	del,MS7
	rjmp	wozwait	
sendlong:
	ldi	tilo,low(longtime)
	rcall	time
	rjmp	timeout
sendshort:
	ldi	tilo,low(shorttime)
	rcall	time
	rjmp	timeout
; this simple routine loads the timer 
; and then waits for it to time out
time:	out	TCNT1,tilo
	ldi	temp,(1<<PSR1)	
	out	GTCCR,temp	; reset prescaler
	ldi	temp,(1<<CS12)|(1<<CS11) |(1<<CS10)	; prescaler / 64 = 8 usec
	out	TCCR1,temp	; start timer
	ret
; wait for the timer to overflow
timeout:	
	in	temp,TIFR
	sbrs	temp,TOV1
	rjmp	timeout
time2:	ldi	temp,(0<<CS11)
	out	TCCR1,temp	; stop timer
	ldi	temp,(1<<TOV1)
	out	TIFR,temp	;clr flag
	ret
; steve wozniak's wait routine - this time for AVR 
; this is the extended routine with del^3 
; this wait routine is ingenious and handles wide ranges of delay 
; as a hommage to steve i port it to all my embedded systems. 
onesec:	ldi	del,second
wozwait: push	del
wwait2:	push	del
wwait1:	subi	del,1	
	brne	wwait1
	pop	del
	subi	del,1
	brne	wwait2
	pop	del
	subi	del,1
	brne	wozwait
	ret
; initialize ports		
; Port B is the only one
init_ports:
;port B
; set state and pullups
	ldi	temp,(0<<TXDATA)|(1<<DATA3)|(1<<DATA2)|(1<<DATA1)|(1<<DATA0)
	out	PortB,temp		; use the pull-ups

	ldi	temp,(1<<TXDATA)
	out	DDRB,temp		; set the output
	ldi	del,0x20		; first settle 
	rcall	wozwait
; 
	ret
; the OFF codes come first
; my home control has the address 30139
; the rct08 controller has this coding scheme:
; 
tx_tab:
	.db	0x30,0x13,0x90,0xff
	.db	0x30,0x13,0x91,0xff
	.db	0x30,0x13,0x92,0xff
	.db	0x30,0x13,0x96,0xff       ;irregular
	.db	0x30,0x13,0x94,0xff
	.db	0x30,0x13,0x95,0xff
	.db	0x30,0x13,0x93,0xff      ;irregular
	.db	0x30,0x13,0x97,0xff
ons_tab:
	.db	0x30,0x13,0x98,0xff
	.db	0x30,0x13,0x99,0xff
	.db	0x30,0x13,0x9a,0xff
	.db	0x30,0x13,0x9e,0xff      ;irregular
	.db	0x30,0x13,0x9c,0xff
	.db	0x30,0x13,0x9d,0xff
	.db	0x30,0x13,0x9b,0xff     ;irregular
	.db	0x30,0x13,0x9f,0xff